netctl/repos/core-any/PKGBUILD

   1 # Maintainer: Jouke Witteveen <j.witteveen@gmail.com>
   2
   3 pkgname=netctl
   4 pkgver=1.28
   5 pkgrel=2
   6 pkgdesc='Profile based systemd network management'
   7 url='https://gitlab.archlinux.org/archlinux/netctl'
   8 license=('GPL')
   9 depends=('coreutils' 'iproute2' 'resolvconf' 'systemd>=233')
  10 # The source tarball includes pre-built (using asciidoc) documentation.
  11 makedepends=('pkg-config')
  12 optdepends=('dialog: for the menu based wifi assistant'
  13             'dhclient: for DHCP support (or dhcpcd)'
  14             'dhcpcd: for DHCP support (or dhclient)'
  15             'wpa_supplicant: for wireless networking support'
  16             'ifplugd: for automatic wired connections through netctl-ifplugd'
  17             'ppp: for PPP connections'
  18             'openvswitch: for Open vSwitch connections'
  19             'wireguard-tools: for WireGuard connections'
  20            )
  21 install=netctl.install
  22 source=(https://sources.archlinux.org/other/packages/netctl/netctl-${pkgver}.tar.xz{,.sig})
  23 arch=('any')
  24 sha256sums=('3d591703b7bc80eb89602040c4a1add4fdf945d13b8e0926a47530260b9adb8d'
  25             'SKIP')
  26 validpgpkeys=('CFA6AF15E5C74149FC1D8C086D1655C14CE1C13E')  # Florian Pritz
  27
  28 package() {
  29   cd "$srcdir/netctl-${pkgver}"
  30   make DESTDIR="$pkgdir" install
  31
  32   # Shell Completion
  33   install -D -m644 contrib/bash-completion "$pkgdir/usr/share/bash-completion/completions/netctl"
  34   ln -s netctl "$pkgdir/usr/share/bash-completion/completions/netctl-auto"
  35   ln -s netctl "$pkgdir/usr/share/bash-completion/completions/wifi-menu"
  36   install -D -m644 contrib/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_netctl"
  37 }
  38