opencolorio/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Dumitru Ursu <dima@ceata.org>
   3
   4 pkgname=opencolorio
   5 pkgver=2.2.1
   6 pkgrel=7
   7 pkgdesc="A color management framework for visual effects and animation"
   8 arch=('x86_64')
   9 url="https://opencolorio.org"
  10 license=('BSD')
  11 depends=('freeglut' 'glew' 'lcms2' 'tinyxml' 'yaml-cpp' 'imath' 'pystring' 'minizip-ng' 'openexr')
  12 makedepends=('cmake' 'python' 'pybind11' 'ninja')
  13 checkdepends=('openimageio')
  14 optdepends=('python: python bindings')
  15 source=($pkgname-$pkgver.tar.gz::https://github.com/AcademySoftwareFoundation/OpenColorIO/archive/v$pkgver.tar.gz)
  16 sha512sums=('d5f3a4b5bd661af7336c015d07e0feccb286464a08239a3c259a97217001161e7571f5137475fc2f4d1b9af6381bbfa03c0b60f41de282f114307961b8d84fc9')
  17
  18 build() {
  19   cd OpenColorIO-$pkgver
  20
  21   CXXFLAGS+=" -ffat-lto-objects"
  22   cmake \
  23     -GNinja \
  24     -Bbuild \
  25     -DCMAKE_BUILD_TYPE=Release \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DCMAKE_INSTALL_LIBDIR=lib \
  28     -DCMAKE_SKIP_INSTALL_RPATH=YES \
  29     -Wno-dev
  30   ninja -C build
  31 }
  32
  33 check() {
  34   cd OpenColorIO-$pkgver/build
  35
  36   ctest -E test_gpu
  37 }
  38
  39 package() {
  40   cd OpenColorIO-$pkgver
  41
  42   DESTDIR="$pkgdir" ninja -C build install
  43   install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
  44 }
  45
  46 # vim:set ts=2 sw=2 et: