openconnect/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Felix Yan <felixonmars@archlinux.org>
   4
   5 pkgname=openconnect
   6 pkgver=9.10
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc='Open client for Cisco AnyConnect VPN'
  10 url='https://www.infradead.org/openconnect/'
  11 arch=('x86_64')
  12 license=('LGPL2.1')
  13 depends=('libxml2' 'gnutls' 'libproxy' 'vpnc' 'krb5' 'lz4' 'pcsclite'
  14          'stoken' 'tpm2-tss' 'oath-toolkit' 'libproxy' 'libp11-kit'
  15          'xdg-utils'
  16          libstoken.so libtss2-esys.so libtss2-mu.so libtss2-tctildr.so
  17          libxml2.so libproxy.so libhogweed.so libp11-kit.so libpskc.so
  18          libgssapi_krb5.so libpcsclite.so)
  19 makedepends=('intltool' 'python')
  20 checkdepends=('python-flask')
  21 optdepends=('python: tncc-wrapper')
  22 provides=('libopenconnect.so')
  23 options=('!emptydirs')
  24 source=(https://www.infradead.org/openconnect/download/openconnect-${pkgver}.tar.gz{,.asc})
  25 sha256sums=('f1e0c4eed0ba79b87d6a0406a1500775c145c7b8392fa82094fc3e37dfab6547'
  26             'SKIP')
  27 validpgpkeys=('BE07D9FD54809AB2C4B0FF5F63762CDA67E2F359') # David Woodhouse <dwmw2@infradead.org>
  28
  29 build() {
  30   cd ${pkgname}-${pkgver}
  31   PYTHON=/usr/bin/python \
  32     ./configure \
  33     --prefix=/usr \
  34     --sbindir=/usr/bin \
  35     --libexecdir=/usr/lib \
  36     --disable-static
  37   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  38   make
  39 }
  40
  41 check() {
  42   cd ${pkgname}-${pkgver}
  43   make check
  44 }
  45
  46 package() {
  47   cd ${pkgname}-${pkgver}
  48   make DESTDIR="${pkgdir}" install
  49 }
  50
  51 # vim: ts=2 sw=2 et: