pam_wrapper/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=pam_wrapper
   4 pkgver=1.1.4
   5 pkgrel=4
   6 pkgdesc="Tool to test PAM applications and PAM modules"
   7 url="https://cwrap.org/pam_wrapper.html"
   8 arch=(x86_64)
   9 license=(GPL3)
  10 depends=(pam python)
  11 makedepends=(git cmake ninja cmocka doxygen graphviz)
  12 provides=(libpam_wrapper.so libpamtest.so)
  13 _commit=d938a84d88c5882a08babfb5e10f03a9135237a3  # tags/pam_wrapper-1.1.4^0
  14 source=("git+https://git.samba.org/pam_wrapper.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^pam_wrapper-//;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   cmake -S $pkgname -B build -G Ninja \
  28     -DCMAKE_INSTALL_PREFIX=/usr \
  29     -DCMAKE_BUILD_TYPE=None \
  30     -DUNIT_TESTING=true
  31   cmake --build build
  32   cmake --build build --target doc
  33 }
  34
  35 check() {
  36   cd build
  37   ctest --output-on-failure --stop-on-failure -j$(nproc)
  38 }
  39
  40 package() {
  41   DESTDIR="$pkgdir" cmake --install build
  42
  43   mkdir -p "$pkgdir/usr/share/doc"
  44   cp -a build/doc/html "$pkgdir/usr/share/doc/$pkgname"
  45   cp -a build/doc/man/man3 "$pkgdir/usr/share/man"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: