perl-image-exiftool/repos/extra-any/PKGBUILD

   1 # Maintainer: Florian Pritz <bluewind@xinu.at>
   2 # Contributor: tobias <tobias@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias@justdreams.de>
   4 # Contributor: Firmicus <francois.archlinux.org>
   5
   6 pkgname=perl-image-exiftool
   7 _srcname=Image-ExifTool
   8 pkgver=12.60
   9 pkgrel=1
  10 pkgdesc="Reader and rewriter of EXIF informations that supports raw files"
  11 arch=('any')
  12 url="https://search.cpan.org/perldoc?exiftool"
  13 license=('GPL')
  14 depends=('perl')
  15 optdepends=('perl-archive-zip: Support for ZIP-files, including EPUB')
  16 provides=("perl-exiftool=$pkgver")
  17 replaces=("perl-exiftool")
  18 options=('!emptydirs')
  19 source=(https://exiftool.org/${_srcname}-$pkgver.tar.gz)
  20 sha256sums=('73dbe06d004c31082a56e78d7f246f2bb0002fbb1835447bc32a2b076f3d32ad')
  21
  22 build() {
  23   cd "${srcdir}/${_srcname}-${pkgver}"
  24   # install module in vendor directories.
  25   perl Makefile.PL INSTALLDIRS=vendor
  26   make
  27 }
  28
  29 check() {
  30   cd "${srcdir}/${_srcname}-${pkgver}"
  31   make test
  32 }
  33
  34 package() {
  35   cd "${srcdir}/${_srcname}-${pkgver}"
  36   make DESTDIR="${pkgdir}" install
  37   install -dm755 "$pkgdir/usr/share/$pkgname"
  38   cp -r fmt_files config_files arg_files "$pkgdir/usr/share/$pkgname"
  39 }