pyatspi/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=pyatspi
   5 pkgname=(python-atspi)
   6 pkgver=2.46.0
   7 pkgrel=2
   8 pkgdesc="Python bindings for D-Bus AT-SPI"
   9 url="https://wiki.linuxfoundation.org/accessibility/atk/at-spi/at-spi_on_d-bus"
  10 arch=(any)
  11 license=(GPL2)
  12 depends=(python-gobject at-spi2-core)
  13 makedepends=(git)
  14 _commit=c9cb2a2289a6eb1fb95b66c25d5351bfea54c47e  # tags/PYATSPI_2_46_0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/pyatspi2.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd pyatspi2
  20   git describe --tags | sed 's/^PYATSPI_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd pyatspi2
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28 build() (
  29   cd pyatspi2
  30   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  31     --with-python=/usr/bin/python
  32   make
  33 )
  34
  35 package_python-atspi() {
  36   cd pyatspi2
  37   make DESTDIR="$pkgdir" install
  38 }
  39
  40 # vim:set sw=2 sts=-1 et: