python-pycurl/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
   4
   5 pkgname=python-pycurl
   6 pkgver=7.45.2
   7 pkgrel=3
   8 pkgdesc="A Python 3.x interface to libcurl"
   9 arch=('x86_64')
  10 url="http://pycurl.sourceforge.net/"
  11 license=('LGPL' 'MIT')
  12 depends=('python' 'curl')
  13 makedepends=('python-setuptools')
  14 checkdepends=('python-bottle' 'python-pytest' 'vsftpd' 'python-flaky' 'python-pyflakes')
  15 source=("https://github.com/pycurl/pycurl/archive/REL_${pkgver//./_}/$pkgname-$pkgver.tar.gz")
  16 sha512sums=('c27d500a310124b0972eaeb424afc2878e0cd59bec9841ec0dcff3485a76e78b53438d9bf9c035658058d7c118e3e5ecd426e0733cbd251261135c6a504f2edf')
  17
  18 prepare() {
  19   mv pycurl-REL_${pkgver//./_} pycurl-$pkgver
  20 }
  21
  22 build() {
  23   cd pycurl-$pkgver
  24   make
  25   python setup.py build
  26 }
  27
  28 check() {
  29   export PYCURL_VSFTPD_PATH=vsftpd
  30   # We don't have HTTP2 enabled
  31
  32   cd pycurl-$pkgver
  33   PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.10:$PYTHONPATH" make test || warning "Tests failed"
  34 }
  35
  36 package() {
  37   cd pycurl-$pkgver
  38   python setup.py install -O1 --root="$pkgdir"
  39   install -Dm644 COPYING-MIT -t "$pkgdir"/usr/share/licenses/$pkgname/
  40 }