python-pytest-qt/repos/extra-any/PKGBUILD

   1 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   2
   3 _name=pytest-qt
   4 pkgname=python-pytest-qt
   5 pkgver=4.2.0
   6 pkgrel=2
   7 pkgdesc='pytest support for PyQt and PySide applications'
   8 arch=(any)
   9 license=('MIT')
  10 url='https://github.com/pytest-dev/pytest-qt'
  11 depends=('python-pytest')
  12 makedepends=('python-setuptools-scm')
  13 checkdepends=('python-pyqt5' 'pyside2' 'xorg-server-xvfb')
  14 source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
  15 sha512sums=('57e175bada0e33101eeb7d85579f6e804658d74168714b117b3a1ba564826405e70860b258caf28c917ddca7acd1842de2133a55b342862762fc37ca1a758b69')
  16
  17 build() {
  18   cd ${_name}-$pkgver
  19   python setup.py build
  20 }
  21
  22 check() {
  23   cd ${_name}-$pkgver/src
  24   PYTHONPATH=. PYTEST_QT_API=pyqt5 xvfb-run pytest --fixtures pytestqt ../tests
  25 }
  26
  27 package() {
  28   cd ${_name}-$pkgver
  29   python setup.py install -O1 --root="${pkgdir}" --skip-build
  30   install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  31 }