python-urwid/repos/community-staging-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Daniel Isenmann <daniel@archlinux.org>
   3 # Contributor: Sergej Pupykin <sergej@aur.archlinux.org>
   4 # Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>
   5
   6 _name=urwid
   7 pkgname=python-urwid
   8 pkgver=2.1.2.r41.g0c0ea37
   9 # somewhere past 2.1.2 as there has not been a release in years ;_;
  10 # https://github.com/urwid/urwid/issues/511
  11 _commit=0c0ea377ab9b418cbb5233fa6e178dd05f1f4e5a
  12 pkgrel=1
  13 pkgdesc='Curses-based user interface library'
  14 url='https://urwid.org/'
  15 arch=('x86_64')
  16 license=('LGPL')
  17 depends=('python' 'glibc')
  18 makedepends=(
  19   'git'
  20   'python-build'
  21   'python-installer'
  22   'python-setuptools'
  23   'python-wheel'
  24 )
  25 source=(
  26   git+https://github.com/$_name/$_name.git#commit=$_commit
  27 )
  28 sha256sums=('SKIP')
  29 sha512sums=('SKIP')
  30
  31 pkgver() {
  32   cd $_name
  33   git describe --long --abbrev=7 | sed 's/^release-//;s/\([^-]*-g\)/r\1/;s/-/./g'
  34 }
  35
  36 build() {
  37   cd $_name
  38   python -m build --wheel --no-isolation
  39 }
  40
  41 check() {
  42   cd $_name
  43   python -m unittest discover -vs $_name/tests
  44 }
  45
  46 package() {
  47   cd $_name
  48   python -m installer --destdir="$pkgdir" dist/*.whl
  49   rm -rv "${pkgdir}"/usr/lib/python*/site-packages/urwid/tests
  50 }
  51
  52 # vim: ts=2 sw=2 et: