rsync/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgname=rsync
   4 _tag='b13e7a8ef4fa430223f66403506fb821caae5cfd' # git rev-parse v${pkgver}
   5 pkgver=3.2.7
   6 pkgrel=4
   7 pkgdesc='A fast and versatile file copying tool for remote and local files'
   8 arch=('x86_64')
   9 url='https://rsync.samba.org/'
  10 license=('GPL3')
  11 depends=('acl' 'libacl.so' 'lz4' 'openssl' 'popt' 'xxhash' 'libxxhash.so'
  12          'zlib' 'zstd')
  13 optdepends=('python: for rrsync')
  14 makedepends=('git' 'python-commonmark')
  15 backup=('etc/rsyncd.conf'
  16         'etc/xinetd.d/rsync')
  17 validpgpkeys=('0048C8B026D4C96F0E589C2F6C859FB14B96A8C5') # Wayne Davison <wayned@users.sourceforge.net>
  18 source=("git+https://github.com/WayneD/rsync#tag=${_tag}?signed"
  19         'rsyncd.conf')
  20 sha256sums=('SKIP'
  21             '733ccb571721433c3a6262c58b658253ca6553bec79c2bdd0011810bb4f2156b')
  22
  23 _backports=(
  24 )
  25
  26 _reverts=(
  27 )
  28
  29 prepare() {
  30   cd "$srcdir/rsync"
  31
  32   local _c
  33   for _c in "${_backports[@]}"; do
  34     if [[ $_c == *..* ]]; then
  35       git log --oneline --reverse "${_c}"
  36     else
  37       git log --oneline -1 "${_c}"
  38     fi
  39     git cherry-pick -n -m1 "${_c}"
  40   done
  41   for _c in "${_reverts[@]}"; do
  42     git log --oneline -1 "${_c}"
  43     git revert -n "${_c}"
  44   done
  45 }
  46
  47 build() {
  48   cd "$srcdir/rsync"
  49
  50   ./configure \
  51     --prefix=/usr \
  52     --disable-debug \
  53     --with-rrsync \
  54     --with-included-popt=no \
  55     --with-included-zlib=no
  56   make
  57 }
  58
  59 check() {
  60   cd "$srcdir/rsync"
  61
  62   make test
  63 }
  64
  65 package() {
  66   cd "$srcdir/rsync"
  67
  68   make DESTDIR="$pkgdir" install
  69   install -Dm0644 ../rsyncd.conf "$pkgdir/etc/rsyncd.conf"
  70   install -Dm0644 packaging/lsb/rsync.xinetd "$pkgdir/etc/xinetd.d/rsync"
  71   install -Dm0644 packaging/systemd/rsync.service "$pkgdir/usr/lib/systemd/system/rsyncd.service"
  72   install -Dm0644 packaging/systemd/rsync.socket "$pkgdir/usr/lib/systemd/system/rsyncd.socket"
  73   install -Dm0644 packaging/systemd/rsync@.service "$pkgdir/usr/lib/systemd/system/rsyncd@.service"
  74 }