scons/repos/community-any/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Ray Rashif <schiv@archlinux.org>
   3 # Contributor: damir <damir@archlinux.org>
   4 # Contributor: Lukas Sabota <punkrockguy318@comcast.net>
   5 # Contributor: Brice Carpentier <brice@dlfp.org>
   6
   7 pkgname=scons
   8 pkgver=4.3.0
   9 pkgrel=1
  10 pkgdesc="Extensible Python-based build utility"
  11 arch=(any)
  12 url="https://scons.org"
  13 license=(MIT)
  14 depends=(python)
  15 makedepends=(python-setuptools python-sphinx python-sphinx_rtd_theme
  16 rst2pdf)
  17 checkdepends=(python-pytest)
  18 source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/${pkgver}.tar.gz")
  19 sha512sums=('2d91cf3045797c888d24db38d5b44576e56b271a2c4e9d28d7e16026451865f713990ff9e57fa3e0a1c19603c2d6adbbd1ba36d297c9dcce4db4139fcc51cd62')
  20 b2sums=('a43b509b358d47ee73f7eb714d1239b4fdc33f38483c1a3e72c3a8082242d7bb1a4925958a2648782aa28f4c22a6e018aea8fec1139cf44c59e859f6f902d1d3')
  21
  22 prepare() {
  23   cd "${pkgname}-${pkgver}"
  24   # fix wrong build target
  25   sed -e 's/bdist_wheel/bdist/g' -i SConstruct
  26 }
  27
  28 build() {
  29   cd "${pkgname}-${pkgver}"
  30   python scripts/scons.py --include-dir= -j1
  31   # copy man pages into place, so that install-data may pick them up
  32   cp -av build/doc/man/* .
  33 }
  34
  35 check() {
  36   cd "${pkgname}-${pkgver}"
  37   python runtest.py --all --unit-only
  38 }
  39
  40 package() {
  41   cd "${pkgname}-${pkgver}"
  42   python setup.py install --optimize=1 --install-data=/usr/share/man/man1/ --root="$pkgdir"
  43   install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  44   install -vDm 644 {{CHANGES,RELEASE}.txt,README.rst} -t "${pkgdir}/usr/share/doc/${pkgname}/"
  45 }