sof-bin/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=sof-bin
   4 pkgname=(
   5   sof-firmware
   6   sof-tools
   7 )
   8 pkgver=2.2.5
   9 pkgrel=1
  10 pkgdesc="Sound Open Firmware"
  11 url="https://www.sofproject.org/"
  12 arch=(x86_64)
  13 license=(
  14   custom:BSD
  15   custom:ISC
  16 )
  17 _binver=v${pkgver}
  18 source=(https://github.com/thesofproject/sof-bin/releases/download/$_binver/sof-bin-$_binver.tar.gz)
  19 b2sums=('681ffbc16d983b795556b00881d59d2a0ba258f89482d6e136ddb61345718802d1b3f7fcc494091337f42f9377a8831d890e2c5de140f083e223f29cc5936742')
  20
  21 package_sof-firmware() {
  22   options+=(!strip)
  23
  24   local fwdir="$pkgdir/usr/lib/firmware/intel"
  25   mkdir -p "$fwdir"
  26
  27   cd sof-bin-$_binver
  28
  29   cp -at "$fwdir" sof-$_binver
  30   ln -sr "$fwdir"/{sof-$_binver,sof}
  31
  32   cp -at "$fwdir" sof-tplg-$_binver
  33   ln -sr "$fwdir"/{sof-tplg-$_binver,sof-tplg}
  34
  35   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  36 }
  37
  38 package_sof-tools() {
  39   pkgdesc+=" - tools"
  40   depends=(alsa-lib)
  41
  42   cd sof-bin-$_binver
  43
  44   install -Dt "$pkgdir/usr/bin" tools-$_binver/*
  45   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: