spice/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Patryk Kowalczyk < patryk at kowalczyk dot ws>
   4
   5 pkgname=spice
   6 pkgver=0.15.1
   7 pkgrel=2
   8 pkgdesc="SPICE server"
   9 arch=('x86_64')
  10 url="https://www.spice-space.org"
  11 license=('LGPL2.1')
  12 depends=('pixman' 'opus' 'libjpeg-turbo' 'glib2' 'libsasl' 'lz4' 'spice-protocol' 'libcacard')
  13 makedepends=('meson' 'python-six' 'python-pyparsing')
  14 checkdepends=('gdk-pixbuf2' 'glib-networking')
  15 provides=('libspice-server.so')
  16 source=("https://www.spice-space.org/download/releases/spice-server/$pkgname-$pkgver.tar.bz2"{,.sig})
  17 sha256sums=('ada9af67ab321916bd7eb59e3d619a4a7796c08a28c732edfc7f02fc80b1a37a'
  18             'SKIP')
  19 validpgpkeys=('206D3B352F566F3B0E6572E997D9123DE37A484F') # Victor Toso <victortoso@redhat.com>
  20
  21 prepare() {
  22   cd $pkgname-$pkgver
  23   sed -i "s/if not version_info.contains('git')/if version_info.length() >= 4/" server/meson.build
  24
  25   sed -i "/meson-dist/d" meson.build
  26 }
  27
  28 build() {
  29   arch-meson "$pkgname-$pkgver" build -D gstreamer=no
  30   ninja -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   DESTDIR="$pkgdir" meson install -C build
  39 }