system-config-printer/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3
   4 pkgname=system-config-printer
   5 pkgver=1.5.18
   6 pkgrel=2
   7 pkgdesc="A CUPS printer configuration tool and status applet"
   8 url="https://github.com/OpenPrinting/system-config-printer"
   9 arch=('x86_64')
  10 license=('GPL')
  11 depends=('python-pycups' 'python-dbus' 'python-pycurl' 'libnotify'
  12          'python-gobject' 'gtk3' 'python-cairo' 'libusb')
  13 makedepends=('xmlto' 'docbook-xsl' 'desktop-file-utils' 'libsecret')
  14 optdepends=('libsecret: password management'
  15             'python-pysmbc: SMB browser support'
  16             'cups-pk-helper: PolicyKit helper to configure cups with fine-grained privileges')
  17 source=(https://github.com/OpenPrinting/system-config-printer/releases/download/v${pkgver}/system-config-printer-${pkgver}.tar.xz{,.asc})
  18 sha256sums=('b1a69e1b4ec2add569a87aeca811a37c5361ee6ae327ec852b79e64223e34bee'
  19             'SKIP')
  20 validpgpkeys=('7082A0A50A2E92640F3880E0E4522DCC9B246FF7') # Zdenek Dohnal (The old 4D4227D7 key revoked) <zdohnal@redhat.com>
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24
  25   ./configure --prefix=/usr \
  26     --sbindir=/usr/bin \
  27     --sysconfdir=/etc \
  28     --with-systemdsystemunitdir=/usr/lib/systemd/system \
  29     --with-udevdir=/usr/lib/udev \
  30     --with-udev-rules \
  31     --with-cups-serverbin-dir=/usr/lib/cups
  32   make
  33 }
  34
  35 package() {
  36   cd ${pkgname}-${pkgver}
  37   make DESTDIR="$pkgdir" install
  38
  39   # Compile *.pyc
  40   find "$pkgdir" -name '*.py' -exec python -mpy_compile {} +
  41   # Compile *.pyo
  42   find "$pkgdir" -name '*.py' -exec python -O -mpy_compile {} +
  43
  44   # fix dbus policy location
  45   install -dm755 "$pkgdir"/usr/share/dbus-1/system.d
  46   mv "$pkgdir"/etc/dbus-1/system.d/* "$pkgdir"/usr/share/dbus-1/system.d
  47   rm -rf "$pkgdir"/etc/dbus-1
  48 }