totem-pl-parser/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem-pl-parser
   5 pkgver=3.26.6
   6 pkgrel=2
   7 pkgdesc="Simple GObject-based library to parse and save a host of playlist formats"
   8 url="https://gitlab.gnome.org/GNOME/totem-pl-parser"
   9 license=(LGPL)
  10 arch=(x86_64)
  11 depends=(glib2 libxml2 libarchive libgcrypt)
  12 makedepends=(gobject-introspection git gtk-doc meson)
  13 checkdepends=(gvfs)
  14 provides=("totem-plparser=$pkgver-$pkgrel" libtotem-plparser{,-mini}.so)
  15 conflicts=(totem-plparser)
  16 replaces=("totem-plparser<=3.26.3-1")
  17 options=(debug)
  18 _commit=1431f520fb82f98873c3870f2bbe8eba4d0e670a  # tags/V_3_26_6^0
  19 source=("git+https://gitlab.gnome.org/GNOME/totem-pl-parser.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/^V_//;s/_/./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build -D enable-gtk-doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }
  43
  44 # vim:set sw=2 sts=-1 et: