totem-pl-parser/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem-pl-parser
   5 pkgver=3.26.6
   6 pkgrel=2
   7 pkgdesc="Simple GObject-based library to parse and save a host of playlist formats"
   8 url="https://gitlab.gnome.org/GNOME/totem-pl-parser"
   9 license=(LGPL)
  10 arch=(x86_64)
  11 depends=(glib2 libxml2 libarchive libgcrypt)
  12 makedepends=(gobject-introspection git gtk-doc meson)
  13 checkdepends=(gvfs)
  14 provides=("totem-plparser=$pkgver-$pkgrel" libtotem-plparser{,-mini}.so)
  15 conflicts=(totem-plparser)
  16 replaces=("totem-plparser<=3.26.3-1")
  17 _commit=1431f520fb82f98873c3870f2bbe8eba4d0e670a  # tags/V_3_26_6^0
  18 source=("git+https://gitlab.gnome.org/GNOME/totem-pl-parser.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/^V_//;s/_/./g;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28 }
  29
  30 build() {
  31   arch-meson $pkgname build -D enable-gtk-doc=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: