totem/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem
   5 pkgver=43.0
   6 pkgrel=2
   7 pkgdesc="Movie player for the GNOME desktop based on GStreamer"
   8 url="https://wiki.gnome.org/Apps/Videos"
   9 arch=(x86_64)
  10 license=(GPL2 custom)
  11 depends=(totem-plparser iso-codes libpeas grilo gsettings-desktop-schemas
  12          python-gobject gnome-desktop gst-plugins-base gst-plugins-good
  13          gst-plugins-bad gst-plugin-gtk libhandy libportal-gtk3)
  14 makedepends=(docbook-xsl gobject-introspection git appstream-glib gtk-doc meson
  15              yelp-tools)
  16 checkdepends=(xorg-server-xvfb)
  17 optdepends=('gst-plugins-ugly: Extra media codecs'
  18             'gst-libav: Extra media codecs'
  19             'grilo-plugins: Media discovery')
  20 provides=(libtotem.so)
  21 conflicts=(totem-plugin)
  22 replaces=(totem-plugin)
  23 groups=(gnome)
  24 options=(debug)
  25 _commit=7bb879e1f6746ca19f99629794e918cdbbd06008  # tags/43.0^0
  26 source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
  27         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  28 sha256sums=('SKIP'
  29             'SKIP')
  30
  31 pkgver() {
  32   cd totem
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd totem
  38
  39   git submodule init
  40   git submodule set-url subprojects/libgd "$srcdir/libgd"
  41   git -c protocol.file.allow=always submodule update
  42 }
  43
  44 build() {
  45   local meson_options=(
  46     -D enable-gtk-doc=true
  47   )
  48
  49   arch-meson totem build "${meson_options[@]}"
  50   meson compile -C build
  51 }
  52
  53 check() {
  54   dbus-run-session xvfb-run -s '-nolisten local' \
  55     meson test -C build --print-errorlogs
  56 }
  57
  58 package() {
  59   meson install -C build --destdir "$pkgdir"
  60   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 totem/COPYING
  61 }
  62
  63 # vim:set sw=2 sts=-1 et: