tracker/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Alexander Fehr <pizzapunk gmail com>
   4
   5 pkgname=tracker
   6 pkgver=2.3.6+r7+gb27396252
   7 pkgrel=2
   8 epoch=1
   9 pkgdesc="Desktop-neutral user information store, search tool and indexer"
  10 url="https://wiki.gnome.org/Projects/Tracker"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp json-glib
  14          libsoup upower libnm)
  15 makedepends=(gobject-introspection vala git bash-completion meson)
  16 checkdepends=(python-gobject python-dbus)
  17 provides=(libtracker-{control,miner,sparql}-2.0.so)
  18 _commit=b2739625209c564192b339814264084046e1cf17  # tracker-2.3
  19 source=("git+https://gitlab.gnome.org/GNOME/tracker.git#commit=$_commit"
  20         0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch)
  21 sha256sums=('SKIP'
  22             '2dc030fb047e99420bd330d5eee1fd70bd26a7ee0adf31f90c724bd0732ed67d')
  23
  24 pkgver() {
  25   cd tracker
  26   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd tracker
  31
  32   # https://gitlab.gnome.org/GNOME/tracker/-/merge_requests/382
  33   git apply -3 ../0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch
  34 }
  35
  36 build() {
  37   arch-meson tracker build
  38   meson compile -C build
  39 }
  40
  41 check() {
  42   dbus-run-session meson test -C build --print-errorlogs -t 3
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "$pkgdir"
  47 }
  48
  49 # vim:set sw=2 et: