usbmuxd/trunk/PKGBUILD

   1 # Maintainer : Ionut Biru <ibiru@archlinux.org>
   2 # Contributor: Gabriel Martinez < reitaka at gmail dot com >
   3
   4 pkgname=usbmuxd
   5 pkgver=1.1.1
   6 pkgrel=3
   7 pkgdesc="USB Multiplex Daemon"
   8 url="https://marcansoft.com/blog/iphonelinux/usbmuxd/"
   9 arch=('x86_64')
  10 license=('GPL2' 'GPL3')
  11 depends=('libimobiledevice' 'libusb' 'libplist')
  12 makedepends=('git' 'systemd')
  13 _commit=79c8b38d1488a6b07e1e68f39d8caec3f1a45622  # tags/1.1.1
  14 source=(
  15   "git+https://github.com/libimobiledevice/usbmuxd#commit=$_commit"
  16   usbmuxd.sysusers
  17   libplist-2.3.0.diff
  18 )
  19 b2sums=('SKIP'
  20         '67a843cd95e750555d1c43c4d01cc90e325ae1b69a5b24bb0e72480b903064f81baeaaa9e1dd95758b456b1444ed869b099be903d6533bb7f5dfe88a87ca1d4e'
  21         '483559477f83f59933d95a8279b21abf92a9d5ad6fe29802ff8966b4a94a79ac80d11f7fc0648846a189484b9f3a7ffa3bd8337940aa255a13ae78b61bb556f4')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30
  31   # Compatibility with libplist 2.3.0
  32   git apply -3 ../libplist-2.3.0.diff
  33
  34   NOCONFIGURE=1 ./autogen.sh
  35 }
  36
  37 check() {
  38   cd $pkgname
  39   make check
  40 }
  41
  42 build() {
  43   cd $pkgname
  44   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin
  45   make
  46 }
  47
  48 package() {
  49   cd $pkgname
  50   make DESTDIR="${pkgdir}" install
  51
  52   install -Dm644 "$srcdir"/usbmuxd.sysusers "$pkgdir"/usr/lib/sysusers.d/usbmuxd.conf
  53 }