vde2/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Sergej Pupykin
   4
   5 _name=vde-2
   6 pkgname=vde2
   7 pkgver=2.3.3
   8 pkgrel=3
   9 pkgdesc="Virtual Distributed Ethernet for emulators like qemu"
  10 arch=(x86_64)
  11 url="https://github.com/virtualsquare/vde-2"
  12 license=(GPL2 LGPL2.1)
  13 depends=(bash glibc)
  14 makedepends=(libpcap wolfssl)
  15 provides=(libvdehist.so libvdemgmt.so libvdeplug.so libvdesnmp.so)
  16 source=($pkgname-$pkgver.tar.gz::https://github.com/virtualsquare/$_name/archive/refs/tags/v$pkgver.tar.gz)
  17 options=(debug)
  18 sha512sums=('d0495aa700984dcc82f85cf7c8125cc10505a8a077fceec45b7fd2bec9c389966381682842e886469fa49239badd9442403d091c2ae5282685085e8262396387')
  19 b2sums=('e3ed7423edc03a6af09967484613c0e2a701f74a4323eeab720cabe9a899120023425527054662ee1dbd207327b7e6dd375bceb4999fd708666df13c08acf348')
  20
  21 prepare() {
  22   cd $_name-$pkgver
  23   autoreconf -fiv
  24 }
  25
  26 build() {
  27   cd $_name-$pkgver
  28   ./configure \
  29     --prefix=/usr \
  30     --sbindir=/usr/bin \
  31     --sysconfdir=/etc \
  32     --libexecdir=/usr/lib/$pkgname \
  33     --enable-experimental
  34   make V=1
  35 }
  36
  37 package() {
  38   depends+=(libpcap.so libwolfssl.so)
  39
  40   make DESTDIR="$pkgdir" install -C $_name-$pkgver
  41   install -vDm 644 $_name-$pkgver/{README,Changelog,doc/{README.*,*-HOWTO}} -t "$pkgdir/usr/share/doc/$pkgname/"
  42 }