vinagre/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Allan McRae <mcrae_allan@hotmail.com>
   4 # Contributor: lp76 <l.peduto@gmail.com>
   5
   6 pkgname=vinagre
   7 pkgver=3.22.0+r160+gc86e114
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc="A VNC Client for the GNOME desktop"
  11 url="https://wiki.gnome.org/Apps/Vinagre"
  12 arch=(x86_64)
  13 license=(GPL)
  14 depends=(libsecret gtk-vnc vte3 telepathy-glib avahi spice-gtk3 gnutls freerdp)
  15 makedepends=(docbook-xsl intltool openssh itstool spice-protocol vala
  16              gnome-common appstream-glib git gobject-introspection)
  17 optdepends=('openssh: SSH plugin')
  18 _commit=c86e114efe31381bff3cad008e9f2cd84a83a803  # master
  19 source=("git+https://gitlab.gnome.org/GNOME/vinagre.git#commit=$_commit")
  20 b2sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29   NOCONFIGURE=1 ./autogen.sh
  30 }
  31
  32 build() {
  33   cd $pkgname
  34   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  35   ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/$pkgname \
  36     --enable-rdp --enable-spice --enable-compile-warnings=minimum
  37   make
  38 }
  39
  40 package() {
  41   cd $pkgname
  42   make DESTDIR="$pkgdir" install
  43 }
  44
  45 # vim:set sw=2 sts=-1 et: