xcb-util-image/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=xcb-util-image
   5 pkgver=0.4.1
   6 pkgrel=2
   7 pkgdesc="Utility libraries for XC Binding - Port of Xlib's XImage and XShmImage functions"
   8 arch=('x86_64')
   9 url="https://xcb.freedesktop.org"
  10 license=('custom')
  11 depends=('libxcb' 'xcb-util')
  12 makedepends=('xorg-util-macros' 'xorgproto')
  13 options=('debug')
  14 source=(https://xorg.freedesktop.org/archive/individual/lib/${pkgname}-${pkgver}.tar.xz{,.sig})
  15 sha512sums=('9b47ba38b91196d76541b6ccabeaf291d3b91036f15422909cd6a79b3fd1a9786d5b1728e411bc41cfdf3d60a253485f4ef7c65ffa6ae646fa93439ec782746e'
  16             'SKIP')
  17 validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # Alan Coopersmith <alan.coopersmith@oracle.com>
  18
  19 build() {
  20   cd ${pkgname}-${pkgver}
  21   ./configure --prefix=/usr --disable-static
  22   make
  23 }
  24
  25 check() {
  26   cd ${pkgname}-${pkgver}
  27   make check
  28 }
  29
  30 package() {
  31   cd ${pkgname}-${pkgver}
  32   make DESTDIR="${pkgdir}" install
  33
  34   install -D -m644 COPYING \
  35     "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
  36 }