xdg-user-dirs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Stefan Husmann <stefan-husmann@t-online.de>
   3 # Contributor:  <mathieu.clabaut@gmail.com>
   4
   5 pkgname=xdg-user-dirs
   6 pkgver=0.18
   7 pkgrel=1
   8 pkgdesc="Manage user directories like ~/Desktop and ~/Music"
   9 url="https://www.freedesktop.org/wiki/Software/xdg-user-dirs"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(sh systemd)
  13 makedepends=(docbook-xsl git)
  14 backup=(etc/xdg/user-dirs.conf etc/xdg/user-dirs.defaults)
  15 install=xdg-user-dirs.install
  16 options=(!emptydirs)
  17 _commit=52e71ff04416f2ca3adaf6d73193de4b8b83de46  # tags/0.18^0
  18 source=("git+https://gitlab.freedesktop.org/xdg/xdg-user-dirs.git#commit=$_commit"
  19         xdg-user-dirs-update.service)
  20 sha256sums=('SKIP'
  21             '53c75f52d782e9492601400236bc8e5bfa76a26f0afd9bce3fe8df1740d341f0')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30   NOCONFIGURE=1 ./autogen.sh
  31 }
  32
  33 build() {
  34   cd $pkgname
  35   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  36   make
  37 }
  38
  39 package() {
  40   cd $pkgname
  41   make DESTDIR="$pkgdir" install
  42
  43   # We use a service
  44   rm "$pkgdir/etc/xdg/autostart/xdg-user-dirs.desktop"
  45   install -Dt "$pkgdir/usr/lib/systemd/user" -m644 ../xdg-user-dirs-update.service
  46 }