xfce4-session/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: tobias <tobias funnychar archlinux.org>
   3
   4 pkgname=xfce4-session
   5 pkgver=4.18.2
   6 pkgrel=1
   7 pkgdesc="Xfce's session manager"
   8 arch=('x86_64')
   9 url="https://docs.xfce.org/xfce/xfce4-session/start"
  10 license=('GPL2')
  11 groups=('xfce4')
  12 depends=('libxfce4ui' 'libwnck3' 'xfconf' 'libsm' 'polkit' 'xorg-iceauth'
  13          'xorg-xinit' 'xorg-xrdb' 'polkit-gnome' 'hicolor-icon-theme')
  14 makedepends=('intltool')
  15 optdepends=('gnome-keyring: for keyring support when GNOME compatibility is enabled'
  16             'xfce4-screensaver: for locking screen with xflock4'
  17             'xscreensaver: for locking screen with xflock4'
  18             'light-locker: for locking screen with xflock4')
  19 source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2
  20         source-system-xinitrc-scripts.patch
  21         xfce-polkit-gnome-authentication-agent-1.desktop)
  22 sha256sums=('01ff7fe8d4c2091adefc2925c6b7bb93152ba0732e95c9b9e64d8207fdbdeb8a'
  23             '6f14d529e4c4f30cd547110bd444cee8dc70c90511a397de18acb6c1fd63ea3e'
  24             '74c94c5f7893d714e04ec7d8b8520c978a5748757a0cdcf5128492f09f31b643')
  25
  26 prepare() {
  27   cd $pkgname-$pkgver
  28
  29   # https://bugzilla.xfce.org/show_bug.cgi?id=15440
  30   patch -Np1 -i ../source-system-xinitrc-scripts.patch
  31 }
  32
  33 build() {
  34   cd $pkgname-$pkgver
  35
  36   ./configure \
  37     --prefix=/usr \
  38     --sysconfdir=/etc \
  39     --localstatedir=/var \
  40     --disable-debug
  41   make
  42 }
  43
  44 package() {
  45   cd $pkgname-$pkgver
  46   make DESTDIR="$pkgdir" install
  47
  48   # Provide a default PolicyKit Authentication Agent (FS#42569)
  49   install -d "$pkgdir/etc/xdg/autostart"
  50   cp "$srcdir/xfce-polkit-gnome-authentication-agent-1.desktop" \
  51     "$pkgdir/etc/xdg/autostart/"
  52 }
  53
  54 # vim:set ts=2 sw=2 et: