xfsprogs/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   2
   3 pkgname=xfsprogs
   4 pkgver=6.2.0
   5 pkgrel=1
   6 pkgdesc="XFS filesystem utilities"
   7 arch=('x86_64')
   8 license=('LGPL')
   9 url="https://xfs.wiki.kernel.org"
  10 depends=('sh' 'util-linux-libs' 'device-mapper' 'libinih' 'liburcu')
  11 optdepends=('icu: for xfs_scrub'
  12             'python: for xfs_scrub_all script'
  13             'smtp-forwarder: for xfs_scrub_fail script')
  14 makedepends=('git' 'icu')
  15 options=('!makeflags')
  16 source=("git+https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git?signed#tag=v${pkgver}")
  17 md5sums=('SKIP')
  18 validpgpkeys=(
  19   '2B8185919E8D248981869DED20AE1692E13DDEE0' # Eric Sandeen <sandeen@sandeen.net>
  20   '4020459E58C1A52511F5399113F703E6C11CF6F0' # Carlos Maiolino <cem@kernel.org>
  21 )
  22
  23 build() {
  24   cd ${pkgname}-dev
  25   make configure
  26   export OPTIMIZER="-march=${CARCH/_/-} -O1"
  27   export DEBUG=-DNDEBUG
  28   ./configure --prefix=/usr --sbindir=/usr/bin --with-systemd-unit-dir=/usr/lib/systemd/system
  29   make
  30 }
  31
  32 package() {
  33   cd ${pkgname}-dev
  34   make DIST_ROOT="${pkgdir}" PKG_ROOT_SBIN_DIR="/usr/bin" install install-dev
  35   chown -R root "$pkgdir"
  36   chgrp -R root "$pkgdir"
  37   # add hack as we cannot set rootlibdir
  38   mv "${pkgdir}"/lib/libhandle.so* "${pkgdir}/usr/lib/"
  39   rm -rf "${pkgdir}/lib"
  40 }