ca-certificates/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Pierre Schmitz <pierre@archlinux.de>
   3
   4 pkgbase=ca-certificates
   5 pkgname=(ca-certificates-utils ca-certificates)
   6 pkgver=20210603
   7 pkgrel=1
   8 pkgdesc="Common CA certificates"
   9 url="https://src.fedoraproject.org/rpms/ca-certificates"
  10 arch=(any)
  11 license=(GPL2)
  12 makedepends=(asciidoc p11-kit)
  13 source=(update-ca-trust update-ca-trust.8.txt 40-update-ca-trust.hook)
  14 sha256sums=('ba98e00f80f94e2648b66252119d1b0da2339b8c83860cd69738e5c4e2d0fcc3'
  15             'acf571f7d7a9df2149a373017280e8f22d07a2d36600256fa48159d22ab74751'
  16             '3a3833ebd6f9cdef2e534a273653f973a4354d4f9368577d0d73236b014b7748')
  17
  18 build() {
  19   asciidoc.py -v -d manpage -b docbook update-ca-trust.8.txt
  20   xsltproc --nonet -o update-ca-trust.8 /etc/asciidoc/docbook-xsl/manpage.xsl update-ca-trust.8.xml
  21 }
  22
  23 package_ca-certificates-utils() {
  24   pkgdesc+=" (utilities)"
  25   depends=(bash coreutils findutils 'p11-kit>=0.24.0')
  26   provides=(ca-certificates ca-certificates-java)
  27   conflicts=(ca-certificates-java)
  28   replaces=(ca-certificates-java)
  29   install=ca-certificates-utils.install
  30
  31   install -Dt "$pkgdir/usr/bin" update-ca-trust
  32   install -Dt "$pkgdir/usr/share/man/man8" -m644 update-ca-trust.8
  33   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  34
  35   # Trust source directories
  36   # Upstream also adds "blocklist" but that's useless without support in p11-kit
  37   install -d "$pkgdir"/{etc,usr/share}/$pkgbase/trust-source/{anchors,blocklist}
  38
  39   # Directories used by update-ca-trust (aka "trust extract-compat")
  40   install -d "$pkgdir"/etc/{ssl/certs/{edk2,java},$pkgbase/extracted}
  41
  42   # Compatibility link for OpenSSL using /etc/ssl as CAdir
  43   # Used in preference to the individual links in /etc/ssl/certs
  44   ln -sr "$pkgdir/etc/$pkgbase/extracted/tls-ca-bundle.pem" "$pkgdir/etc/ssl/cert.pem"
  45
  46   # Compatiblity link for legacy bundle
  47   ln -sr "$pkgdir/etc/$pkgbase/extracted/tls-ca-bundle.pem" "$pkgdir/etc/ssl/certs/ca-certificates.crt"
  48 }
  49
  50 package_ca-certificates() {
  51   pkgdesc+=" (default providers)"
  52   depends=(ca-certificates-mozilla)
  53   conflicts=('ca-certificates-cacert<=20140824-4')
  54   replaces=("${conflicts[@]}")
  55 }
  56
  57 # vim:set et sw=2: