gnome-shell-extensions/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-shell-extensions
   4 pkgver=43.1
   5 pkgrel=1
   6 pkgdesc="Extensions for GNOME shell, including classic mode"
   7 url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
   8 arch=(any)
   9 license=(GPL)
  10 depends=(gnome-shell)
  11 makedepends=(meson git sassc)
  12 optdepends=('gnome-menus: applications menu extension')
  13 groups=(gnome)
  14 _commit=de48d02c625a8a4177ff82899d68420e1585b028  # tags/43.1^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-shell-extensions.git#commit=$_commit"
  16         "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git")
  17 sha256sums=('SKIP'
  18             'SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27
  28   git submodule init
  29   git submodule set-url data/gnome-shell-sass "$srcdir/gnome-shell-sass"
  30   git -c protocol.file.allow=always submodule update
  31 }
  32
  33 build() {
  34   local meson_options=(
  35     -D extension_set=all
  36     -D classic_mode=true
  37   )
  38
  39   arch-meson $pkgname build "${meson_options[@]}"
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   meson test -C build --print-errorlogs
  45 }
  46
  47 package() {
  48   meson install -C build --destdir "$pkgdir"
  49 }
  50
  51 # vim:set sw=2 sts=-1 et: