libpcap/repos/core-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@mirantis.com>
   3 # Contributor: Thomas Bächler <thomas@archlinux.org>
   4
   5 pkgname=libpcap
   6 pkgver=1.10.3
   7 pkgrel=1
   8 pkgdesc='A system-independent interface for user-level packet capture'
   9 arch=(x86_64)
  10 url='https://www.tcpdump.org/'
  11 license=(BSD)
  12 depends=(glibc libnl sh)
  13 makedepends=(bluez-libs dbus)
  14 provides=(libpcap.so)
  15 options=(debug)
  16 source=(https://www.tcpdump.org/release/$pkgname-$pkgver.tar.gz{,.sig})
  17 sha512sums=('57bc07cbc8c326e203ce10ce1eb9f55760fc33320718d8643c65a68949334291877dffcf19af5f61eb9b4eda2d8ffe7bacee38363d2d6536cc85ae81c851684d'
  18             'SKIP')
  19 b2sums=('3614042f7d8cd5a25221f52d2ed09f9f44643cdc0901ff21041ddb7ba85193c667036f7d989c8b59e6e205d630e062da46533110914dd287013a9ff80b31e97f'
  20         'SKIP')
  21 validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D') # The Tcpdump Group
  22
  23 prepare() {
  24   cd $pkgname-$pkgver
  25   autoreconf -fiv
  26 }
  27
  28 build() {
  29   local configure_options=(
  30     --prefix=/usr
  31     --enable-ipv6
  32     --enable-bluetooth
  33     --enable-usb
  34     --with-libnl
  35   )
  36   cd $pkgname-$pkgver
  37   ./configure "${configure_options[@]}"
  38   make
  39 }
  40
  41 package() {
  42   depends+=(libdbus-1.so)
  43
  44   cd $pkgname-$pkgver
  45   make DESTDIR="$pkgdir" install
  46   install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  47   install -vDm 644 {CHANGES,{CONTRIBUTING,README}.md} -t "$pkgdir/usr/share/doc/$pkgname/"
  48 }