power-profiles-daemon/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: tinywrkb <tinywrkb@gmail.com>
   3
   4 pkgname=power-profiles-daemon
   5 pkgver=0.12
   6 pkgrel=1
   7 pkgdesc='Makes power profiles handling available over D-Bus'
   8 url='https://gitlab.freedesktop.org/hadess/power-profiles-daemon'
   9 license=(GPL3)
  10 arch=(x86_64)
  11 depends=(upower polkit)
  12 optdepends=('python-gobject: for powerprofilesctl')
  13 makedepends=(meson)
  14 checkdepends=(python-dbusmock python-isort python-mccabe umockdev)
  15 source=(https://gitlab.freedesktop.org/hadess/power-profiles-daemon/-/archive/$pkgver/$pkgname-$pkgver.tar.gz)
  16 b2sums=('7e78744186d1175d7dc67e3fe84481f68e14ed409639a44bd834ffae820b0828428271360f4f7faa0e2c2323f2ce4d1061e1b260b74aaf5da5cd35881def4a6f')
  17
  18 build() {
  19   meson $pkgname-$pkgver build \
  20     --prefix /usr \
  21     --libexec lib \
  22     --sysconfdir /usr/share
  23   meson compile -C build
  24 }
  25
  26 check() {
  27   meson test -C build
  28 }
  29
  30 package() {
  31   meson install -C build --destdir "$pkgdir"
  32 }