pyqt5/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4 # Contributor: Yichao Yu <yyc1992@gmail.com>
   5 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   6 # Contributor: riai <riai@bigfoot.com> Ben <ben@benmazer.net>
   7
   8 pkgbase=pyqt5
   9 pkgname=('python-pyqt5')
  10 pkgdesc="A set of Python bindings for the Qt5 toolkit"
  11 pkgver=5.15.9
  12 pkgrel=1
  13 arch=('x86_64')
  14 url="https://riverbankcomputing.com/software/pyqt/intro"
  15 license=('GPL')
  16 groups=(pyqt5)
  17 depends=('python-pyqt5-sip' 'qt5-base')
  18 optdepends=('python-opengl: enable OpenGL 3D graphics in PyQt applications'
  19             'python-dbus: for python-dbus mainloop support'
  20             'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
  21             'qt5-tools: QtHelp, QtDesigner'
  22             'qt5-svg: QtSvg'
  23             'qt5-xmlpatterns: QtXmlPatterns'
  24             'qt5-declarative: QtQml, qmlplugin'
  25             'qt5-serialport: QtSerialPort'
  26             'qt5-websockets: QtWebSockets'
  27             'qt5-connectivity: QtNfc, QtBluetooth'
  28             'qt5-x11extras: QtX11Extras'
  29             'qt5-remoteobjects: QtRemoteObjects'
  30             'qt5-speech: QtTextToSpeech'
  31             'qt5-quick3d: QtQuick3D'
  32             'qt5-location: QtLocation, QtPositioning'
  33             'qt5-sensors: QtSensors'
  34             'qt5-webchannel: QtWebChannel')
  35 provides=(qt5-python-bindings)
  36 makedepends=('sip' 'pyqt-builder' 'python-opengl' 'python-dbus'
  37              'qt5-connectivity' 'qt5-multimedia' 'qt5-tools' 'qt5-serialport' 'qt5-speech' 'qt5-svg'
  38              'qt5-websockets' 'qt5-x11extras' 'qt5-xmlpatterns' 'qt5-remoteobjects' 'qt5-quick3d'
  39              'qt5-sensors' 'qt5-webchannel' 'qt5-location')
  40 conflicts=('pyqt5-common')
  41 source=("https://pypi.python.org/packages/source/P/PyQt5/PyQt5-$pkgver.tar.gz")
  42 sha256sums=('dc41e8401a90dc3e2b692b411bd5492ab559ae27a27424eed4bd3915564ec4c0')
  43
  44 build() {
  45   cd PyQt5-$pkgver
  46   sip-build \
  47     --confirm-license \
  48     --no-make \
  49     --api-dir /usr/share/qt/qsci/api/python \
  50     --pep484-pyi
  51   cd build
  52   make
  53 }
  54
  55 package_python-pyqt5(){
  56   cd PyQt5-$pkgver/build
  57   make INSTALL_ROOT="$pkgdir" install
  58
  59   # Remove unused py2 version of uic modules:
  60   rm -r "$pkgdir"/usr/lib/python*/site-packages/PyQt5/uic/port_v2
  61
  62   # compile Python bytecode
  63   python -m compileall -d / "$pkgdir"/usr/lib
  64   python -O -m compileall -d / "$pkgdir"/usr/lib
  65 }