aisleriot/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=aisleriot
   4 pkgver=3.22.14
   5 pkgrel=1
   6 pkgdesc="A collection of patience games written in guile scheme"
   7 url="https://wiki.gnome.org/Apps/Aisleriot"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(guile gtk3 librsvg libcanberra dconf)
  11 makedepends=(git meson yelp-tools appstream-glib)
  12 optdepends=('pysolfc: PySol card sets'
  13             'pysolfc-cardsets: PySol card sets')
  14 _commit=c8470e3f19798f11810275818a05f6a2a6e28f0c  # tags/3.22.14^0
  15 source=("git+https://gitlab.gnome.org/GNOME/aisleriot.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build \
  29     -D theme_kde=false \
  30     -D theme_pysol=true \
  31     -D theme_pysol_path=/usr/share/PySolFC
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   DESTDIR="$pkgdir" meson install -C build
  41 }
  42
  43 # vim:set sw=2 et: