alsa-plugins/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   3 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   4 # Contributor: Daniel Ehlers <danielehlers@mindeye.net>
   5
   6 pkgbase=alsa-plugins
   7 pkgname=(alsa-plugins pulseaudio-alsa)
   8 pkgver=1.2.6
   9 pkgrel=1
  10 epoch=1
  11 pkgdesc="Additional ALSA plugins"
  12 arch=(x86_64)
  13 url="https://www.alsa-project.org"
  14 license=(LGPL2.1)
  15 makedepends=(alsa-lib dbus jack libavtp libpulse libsamplerate speexdsp)
  16 source=("https://www.alsa-project.org/files/pub/plugins/$pkgbase-$pkgver.tar.bz2"{,.sig}
  17         pulse-sysdefault.diff)
  18 sha512sums=('ac54a6f227f1ca5f6e01e08d869e7c06f4bcd68f148932e1902a6fcf3e5ccd3667ac4d8c1a00b77e4b5cb27e17c01cf7526ded4aaf35c4b26fc69e14e6e341f9'
  19             'SKIP'
  20             'b8c8e55f4da0ae87cc44d75a906d00b4f1e2304e6bc10419c6e0913c8f7d29599a3f3d41733decbe412a4669ea0d5af2a57f85b1655fba3625fbbd33c956f3f9')
  21 b2sums=('bead0b9514725560a4fb738c4b1e14b148bf888cc82e0d7611cb6c494ed97a7e366b57f233095372c26a7bd614655bd58a6505202910de421561b540c94d5cca'
  22         'SKIP'
  23         '83c16b77c1737b2b59b60302be22b63e53026a366799fd97fe3c03b86756063d1b9689d5ffc7c793b40db55bdb79a5b6d72a17e0c8aa32364d6e639cf7ad3ce0')
  24 validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release@alsa-project.org>
  25
  26 prepare() {
  27   cd $pkgbase-$pkgver
  28
  29   # Make use of the pulse plugin's "fallback" feature
  30   # Keeps parity with our old config from pulseaudio-alsa
  31   patch -Np1 -i ../pulse-sysdefault.diff
  32
  33   # a52, lavrate plugins not compatible with ffmpeg >= 4.0
  34   # https://mailman.alsa-project.org/pipermail/alsa-devel/2019-December/159425.html
  35   # https://bugs.archlinux.org/task/60586
  36   autoreconf -fvi
  37 }
  38
  39 build() {
  40   cd $pkgbase-$pkgver
  41   ./configure \
  42     --prefix=/usr \
  43     --sysconfdir=/etc \
  44     --enable-maemo-plugin \
  45     --enable-maemo-resource-manager
  46   make
  47 }
  48
  49 package_alsa-plugins() {
  50   depends=(glibc libasound.so)
  51   optdepends=('dbus: for maemo plugin'
  52               'jack: for pcm_jack plugin'
  53               'libavtp: for pcm_aaf plugin'
  54               'libsamplerate: for rate_samplerate plugin'
  55               'libpulse: for conf_pulse, ctl_pulse and pcm_pulse plugins'
  56               'speexdsp: for pcm_speex and rate_speexrate plugins')
  57
  58   cd $pkgbase-$pkgver
  59   make DESTDIR="$pkgdir" install
  60   install -Dt "$pkgdir/usr/share/doc/$pkgbase" -m644 doc/README* doc/*.txt
  61
  62   # remove maemo plugin configuration (it overrides defaults for pcm and ctl),
  63   # until a better way is found to package default overrides:
  64   # https://bugs.archlinux.org/task/65440
  65   rm -v "${pkgdir}/etc/alsa/conf.d/98-maemo.conf"
  66
  67   # make a proper off-by-default config template out of the example file
  68   mv -v "${pkgdir}/etc/alsa/conf.d/99-pulseaudio-default.conf.example" \
  69     "${pkgdir}/usr/share/alsa/alsa.conf.d/99-pulseaudio-default.conf"
  70 }
  71
  72 package_pulseaudio-alsa() {
  73   pkgdesc="ALSA Configuration for PulseAudio"
  74   depends=('alsa-plugins>=1.2.2-2' pulseaudio)
  75
  76   mkdir -p "${pkgdir}/etc/alsa/conf.d"
  77   ln -st "${pkgdir}/etc/alsa/conf.d" \
  78     /usr/share/alsa/alsa.conf.d/99-pulseaudio-default.conf
  79 }
  80
  81 # vim:set sw=2 et: