autogen/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Arjan Timmerman <arjan@soufly.nl>
   3 # Contributor: Tor Krill
   4
   5 pkgname=autogen
   6 pkgver=5.18.16
   7 pkgrel=2
   8 pkgdesc="A tool designed to simplify the creation and maintenance of programs that contain large amounts of repetitious text"
   9 arch=('x86_64')
  10 url="https://www.gnu.org/software/autogen/"
  11 license=('GPL3')
  12 depends=('guile' 'libxml2' 'perl')
  13 makedepends=('autogen' 'chrpath')
  14 source=(https://ftp.gnu.org/gnu/${pkgname}/rel${pkgver}/${pkgname}-${pkgver}.tar.xz{,.sig})
  15 validpgpkeys=('44A088E295C3A722C450590EC9EF76DEB74EE762'
  16               '3EEE51D1355B8EC40D9F3122495143D05D0712D1') # Bruce Korb <bkorb@gnu.org>
  17 sha512sums=('5f12c982dbe27873f5649a96049bf019ff183c90cc0c8a9196556b0ca02e72940cd422f6d6601f68cc7d8763b1124f2765c3b1a6335fc92ba07f84b03d2a53a1'
  18             'SKIP')
  19
  20 prepare() {
  21   cd $pkgname-$pkgver
  22   sed -i 's/ -Werror / /' configure
  23 }
  24
  25 build() {
  26   cd "${srcdir}/${pkgname}-${pkgver}"
  27   ./configure --prefix=/usr
  28   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  29   make
  30 }
  31
  32 check() {
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34   make check -j1
  35 }
  36
  37 package() {
  38   cd "${srcdir}/${pkgname}-${pkgver}"
  39   make DESTDIR="${pkgdir}" install
  40
  41   # Remove unrequired RPATH from binaries
  42   for i in ${pkgdir}/usr/bin/*; do
  43     if chrpath --list "$i"; then
  44       chrpath --delete "$i";
  45     fi
  46   done
  47 }