conky/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: James Rayner <james@archlinux.org>
   5 # Contributor: Partha Chowdhury <kira.laucas@gmail.com>
   6
   7 pkgname=conky
   8 pkgver=1.12.2
   9 _gitcommit=52e5aa53b4c76973519a770949dc8bdca0145325
  10 pkgrel=1
  11 pkgdesc='Lightweight system monitor for X'
  12 url='https://github.com/brndnmtthws/conky'
  13 license=('BSD' 'GPL')
  14 arch=('x86_64')
  15 makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
  16 depends=(
  17   'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
  18   'libxml2' 'libpulse' 'libxnvctrl' 'systemd-libs' 'ncurses' 'curl'
  19   libncursesw.so libXNVCtrl.so libsystemd.so libpulse.so libcurl.so)
  20 source=("git+https://github.com/brndnmtthws/conky.git#tag=${_gitcommit}?signed")
  21 sha512sums=('SKIP')
  22 b2sums=('SKIP')
  23 validpgpkeys=(
  24   'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
  25 )
  26
  27 pkgver() {
  28   cd ${pkgname}
  29   git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  30 }
  31
  32 build() {
  33   cd ${pkgname}
  34   cmake \
  35     -B build \
  36     -D CMAKE_BUILD_TYPE=Release \
  37     -D MAINTAINER_MODE=ON \
  38     -D BUILD_DOCS=ON \
  39     -D BUILD_WLAN=ON \
  40     -D BUILD_XDBE=ON \
  41     -D BUILD_XSHAPE=ON \
  42     -D BUILD_IMLIB2=ON \
  43     -D BUILD_CURL=ON \
  44     -D BUILD_RSS=ON \
  45     -D BUILD_NVIDIA=ON \
  46     -D BUILD_WEATHER_METAR=ON \
  47     -D BUILD_PULSEAUDIO=ON \
  48     -D BUILD_JOURNAL=ON \
  49     -D CMAKE_INSTALL_PREFIX=/usr \
  50     -Wno-dev \
  51     -S .
  52
  53   make -C build
  54 }
  55
  56 package() {
  57   cd ${pkgname}
  58   make -C build DESTDIR="${pkgdir}" install
  59   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  60   install -Dm 644 extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
  61   install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
  62 }
  63
  64 # vim: ts=2 sw=2 et: