eog-plugins/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=eog-plugins
   4 pkgver=3.26.7
   5 pkgrel=3
   6 pkgdesc="Plugins for Eye of Gnome"
   7 arch=(x86_64)
   8 url="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
   9 license=(GPL2)
  10 depends=(eog libchamplain libgdata python-gobject)
  11 makedepends=(intltool gobject-introspection git)
  12 _commit=74e84f4665aace0ded73793d882050d691bf9fb6  # tags/3.26.7^0
  13 source=("git+https://gitlab.gnome.org/GNOME/eog-plugins.git#commit=$_commit")
  14 sha512sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   git describe --tags | sed 's/-/+/g'
  19 }
  20
  21 prepare() {
  22   cd $pkgname
  23   NOCONFIGURE=1 ./autogen.sh
  24 }
  25
  26 build() {
  27   cd $pkgname
  28   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  29   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  30   make
  31 }
  32
  33 package() {
  34   cd $pkgname
  35   make DESTDIR="$pkgdir" install
  36 }
  37
  38 # vim:set ts=2 sw=2 et: