gn-m87/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2
   3 pkgname=gn-m87
   4 pkgver=0.1831.e002e68a
   5 _commit=e002e68a48d1c82648eadde2f6aafa20d08c36f2
   6 pkgrel=1
   7 pkgdesc="Meta-build system that generates build files for Ninja"
   8 pkgdesc+=" (version shipped in Chromium 87; for apps using the set_sources_assignment_filter function; https://crbug.com/1018739)"
   9 arch=('x86_64')
  10 url="https://gn.googlesource.com/gn/"
  11 license=('BSD')
  12 depends=('gcc-libs')
  13 makedepends=('clang' 'ninja' 'python' 'git')
  14 source=(git+https://gn.googlesource.com/gn#commit=$_commit)
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd gn
  19   echo 0.$(git rev-list --count initial-commit..).$(git rev-parse --short HEAD)
  20 }
  21
  22 build() {
  23   cd gn
  24   ./build/gen.py
  25   ninja -C out
  26 }
  27
  28 check() {
  29   cd gn
  30   ./out/gn_unittests
  31 }
  32
  33 package() {
  34   cd gn
  35   install -D out/gn "$pkgdir/usr/bin/gn-m87"
  36   install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*
  37   install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  38 }
  39
  40 # vim:set ts=2 sw=2 et: