gnome-shell/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Flamelab <panosfilip@gmail.com
   4
   5 pkgname=gnome-shell
   6 pkgver=41.1
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="Next generation desktop shell"
  10 url="https://wiki.gnome.org/Projects/GnomeShell"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gtk4
  14          gnome-settings-daemon gnome-themes-extra gsettings-desktop-schemas
  15          libcanberra-pulse libgdm libsecret mutter nm-connection-editor unzip
  16          gstreamer libibus gnome-autoar gnome-disk-utility gst-plugin-pipewire
  17          libsoup3)
  18 makedepends=(gtk-doc gnome-control-center evolution-data-server
  19              gobject-introspection git meson sassc asciidoc bash-completion)
  20 checkdepends=(xorg-server-xvfb)
  21 optdepends=('gnome-control-center: System settings'
  22             'evolution-data-server: Evolution calendar integration')
  23 groups=(gnome)
  24 _commit=a1b537eebf1b7cfb7249fa33c7fbb9ee6ac55b69  # tags/41.1^0
  25 source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
  26         "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
  27 sha256sums=('SKIP'
  28             'SKIP')
  29
  30 pkgver() {
  31   cd $pkgname
  32   git describe --tags | sed 's/-/+/g'
  33 }
  34
  35 prepare() {
  36   cd $pkgname
  37
  38   git submodule init
  39   git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
  40   git submodule update
  41 }
  42
  43 build() {
  44   arch-meson $pkgname build -D gtk_doc=true
  45   meson compile -C build
  46 }
  47
  48 check() (
  49   mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
  50   export XDG_RUNTIME_DIR
  51
  52   dbus-run-session xvfb-run -s '-nolisten local' \
  53     meson test -C build --print-errorlogs
  54 )
  55
  56 package() {
  57   depends+=(libmutter-9.so)
  58   meson install -C build --destdir "$pkgdir"
  59 }