gnome-sound-recorder/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-sound-recorder
   5 pkgver=40.0
   6 pkgrel=1
   7 pkgdesc="A utility to make simple audio recording from your GNOME desktop"
   8 url="https://wiki.gnome.org/Apps/SoundRecorder"
   9 arch=(any)
  10 license=(GPL)
  11 depends=(gtk3 gjs gst-plugins-good gst-plugins-base gst-plugins-bad-libs
  12          libhandy)
  13 makedepends=(gobject-introspection git meson)
  14 groups=(gnome-extra)
  15 _commit=db39a5f0f92a66f66fc1017f28223b30dc072a20  # tags/40.0^0
  16 source=("git+https://gitlab.gnome.org/GNOME/gnome-sound-recorder.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   DESTDIR="$pkgdir" meson install -C build
  39 }
  40
  41 # vim:set sw=2 et: