gnu-efi/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 pkgname=gnu-efi
   4 pkgver=3.0.14
   5 pkgrel=1
   6 pkgdesc="Develop EFI applications using the GNU toolchain and the EFI development environment"
   7 arch=('x86_64')
   8 url="https://sourceforge.net/projects/gnu-efi/"
   9 license=('BSD')
  10 conflicts=('gnu-efi-libs')
  11 provides=('gnu-efi-libs')
  12 replaces=('gnu-efi-libs')
  13 source=("https://download.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
  14         "${pkgname}-3.0.12-ldflags.patch")
  15 sha512sums=('37420ba3804e8547451a7b143a689ceb6af0557234fa7801efdeba3c2fc581a5354fe34cbaacb338d7b394d913e7274098ebf07026b7c1d50b2236d7f86c470c'
  16             '7fd1c8d09ff870c33ae62887b657a7367f85a07f6709d33471ca13117a08e755853fd1e99db492d1db47444b95ae871078c4a913ed70aa7236e49349046e06b6')
  17 b2sums=('c7f9127d3bb7e5e2bc52f5fc7be3376ddc5076b262e5db5a30a997cf10bf10288da63ded64d11327fad09190a803ce26e82b32aea2d8525ee0d1e1a23ebadff2'
  18         'c1633240ee6363c1df2ae5d7aab5a76a8fe93fd86a2c9a4973b8b30273e1512914c67c88483d0880cfca00df38b3b62fe9e1cd173b139b622ee83f0db835320f')
  19
  20 prepare() {
  21   cd "$pkgname-$pkgver"
  22   # -Werror, not even once
  23   sed -e 's/-Werror//g' -i Make.defaults
  24   # insert LDFLFAGS into custom linker for apps
  25   patch -Np1 -i "../${pkgname}-3.0.12-ldflags.patch"
  26 }
  27
  28 build() {
  29   cd "$pkgname-$pkgver"
  30   make
  31   make -C lib
  32   make -C gnuefi
  33   make -C inc
  34   # unset LDFLAGS for custom linker used in apps, as we have patched our
  35   # LDFLAGS in manually in prepare()
  36   LDFLAGS=""
  37   make -C apps
  38 }
  39
  40 package() {
  41   cd "$pkgname-$pkgver"
  42   make INSTALLROOT="$pkgdir/" PREFIX='/usr' install
  43   install -vDm 644 apps/*.efi -t "${pkgdir}/usr/share/${pkgname}/apps/$CARCH"
  44   install -vDm 644 README.efilib -t "${pkgdir}/usr/share/licenses/${pkgname}"
  45   install -vDm 644 {ChangeLog,README.{gnuefi,git,elilo}} \
  46     -t "${pkgdir}/usr/share/doc/${pkgname}"
  47 }