libcbor/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Moritz Kiefer <moritz.kiefer@purelyfunctional.org>
   3
   4 pkgname=libcbor
   5 pkgver=0.8.0
   6 pkgrel=1
   7 pkgdesc='C library for parsing and generating CBOR, the general-purpose schema-less binary data format'
   8 url='https://github.com/PJK/libcbor'
   9 arch=('x86_64')
  10 license=('MIT')
  11 depends=('glibc')
  12 makedepends=('cmake' 'cmocka')
  13 provides=('libcbor.so')
  14 source=(https://github.com/PJK/libcbor/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('694d2d3a78d80072f96e0afb73590ca1f3572e41d2117330ef4313ed06271743b048d3ba3259c6ffe9a802d5e441379d0e54787d1d42fed08dc81ac4f06c6dbc')
  16 b2sums=('e8548e7351984ebdcbeb5f13a7ca35412c3f3f05e2a44a5438d57b90bdcdc51f5265953163106f90ade911a96af665956ebeba7ed1c48cf207acf6d683af5606')
  17
  18 build() {
  19   cd ${pkgname}-${pkgver}
  20   cmake . \
  21     -Bbuild \
  22     -DCMAKE_INSTALL_PREFIX=/usr \
  23     -DCMAKE_INSTALL_LIBDIR=lib \
  24     -DCMAKE_BUILD_TYPE=Release \
  25     -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
  26     -DBUILD_SHARED_LIBS=ON \
  27     -DWITH_TESTS=1
  28   make -C build VERBOSE=1
  29   make -C build/test VERBOSE=1
  30 }
  31
  32 check() {
  33   cd ${pkgname}-${pkgver}
  34   make -C build/test test
  35 }
  36
  37 package() {
  38   cd ${pkgname}-${pkgver}
  39   make -C build DESTDIR="${pkgdir}" install
  40   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  41   install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
  42 }
  43
  44 # vim: ts=2 sw=2 et: