libevent/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Tom Gundersen <teg@jklm.no>
   2 # Contributor: Judd <jvinet@zeroflux.org>
   3
   4 pkgname=libevent
   5 pkgver=2.1.12
   6 pkgrel=1
   7 pkgdesc="An event notification library"
   8 arch=('x86_64')
   9 url="https://libevent.org/"
  10 license=('BSD')
  11 depends=('openssl')
  12 makedepends=('cmake' 'python')
  13 optdepends=('python: to use event_rpcgen.py')
  14 source=(https://github.com/libevent/libevent/releases/download/release-$pkgver-stable/$pkgname-$pkgver-stable.tar.gz{,.asc})
  15 sha256sums=('92e6de1be9ec176428fd2367677e61ceffc2ee1cb119035037a27d346b0403bb'
  16             'SKIP')
  17 validpgpkeys=('B35BF85BF19489D04E28C33C21194EBB165733EA'
  18               '9E3AC83A27974B84D1B3401DB86086848EF8686D')
  19
  20 build() {
  21   cd ${pkgname}-${pkgver}-stable
  22   cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DEVENT__LIBRARY_TYPE=SHARED -S . -B build
  23   cmake --build build
  24 }
  25
  26 check() {
  27   cd ${pkgname}-${pkgver}-stable
  28   cmake --build build --target test
  29 }
  30
  31 package() {
  32   cd ${pkgname}-${pkgver}-stable
  33   cmake --build build --target install -- DESTDIR="$pkgdir"
  34   install -Dm 644 LICENSE "${pkgdir}"/usr/share/licenses/libevent/LICENSE
  35 }