libgweather/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libgweather
   5 pkgver=40.0
   6 pkgrel=1
   7 pkgdesc="Location and timezone database and weather-lookup library"
   8 url="https://wiki.gnome.org/Projects/LibGWeather"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(libsoup gtk3 geocode-glib dconf)
  12 makedepends=(gobject-introspection vala git gtk-doc glade meson python-gobject)
  13 provides=(libgweather-3.so)
  14 _commit=85e157dade2ce9f252c93e8ec2b7a88f6fe78016  # tags/40.0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/libgweather.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/\.beta/beta/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build -D gtk_doc=true
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   # Test fails without fr_FR.UTF-8 locale
  34   meson test -C build --print-errorlogs || :
  35 }
  36
  37 package() {
  38   DESTDIR="$pkgdir" meson install -C build
  39 }