libtiff/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=libtiff
   5 pkgver=4.3.0
   6 pkgrel=1
   7 pkgdesc='Library for manipulation of TIFF images'
   8 url='http://www.simplesystems.org/libtiff/'
   9 arch=('x86_64')
  10 license=('custom')
  11 depends=('glibc' 'libjpeg' 'libjpeg.so' 'zlib' 'xz' 'zstd')
  12 makedepends=('freeglut' 'glu' 'mesa' 'jbigkit')
  13 optdepends=('freeglut: for using tiffgt')
  14 provides=('libtiff.so' 'libtiffxx.so')
  15 source=(https://download.osgeo.org/libtiff/tiff-${pkgver}.tar.gz{,.sig})
  16 sha256sums=('0e46e5acb087ce7d1ac53cf4f56a09b221537fc86dfc5daaad1c2e89e1b37ac8'
  17             'SKIP')
  18 b2sums=('433a087249541f6142dd25b6dc807018639908175b0d73b4af3aa301af2dee3d76184e4689e7b2f1f9b73567ac78d50456ee94fffe00bad6da05375cf2d94d92'
  19         'SKIP')
  20 validpgpkeys=('EBDFDB21B020EE8FD151A88DE301047DE1198975'  # Bob Friesenhahn <bfriesen@simple.dallas.tx.us>
  21               'B1FA7D81EEB8E66399178B9733EBBFC47B3DD87D') # Even Rouault <even.rouault@spatialys.com>
  22
  23 build() {
  24   cd tiff-${pkgver}
  25   ./configure \
  26     --prefix=/usr \
  27           --sysconfdir=/etc \
  28           --mandir=/usr/share/man \
  29     --with-docdir=/usr/share/doc/${pkgname}
  30   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  31   make
  32 }
  33
  34 check() {
  35   cd tiff-${pkgver}
  36   make check
  37 }
  38
  39 package() {
  40   cd tiff-${pkgver}
  41   make DESTDIR="${pkgdir}" install
  42   install -Dm 644 COPYRIGHT -t "${pkgdir}/usr/share/licenses/${pkgname}"
  43 }
  44
  45 # vim: ts=2 sw=2 et: