libtool/trunk/PKGBUILD

   1 # Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2 # Contributor: Allan McRae <allan@archlinux.org>
   3 # Contributor: judd <jvinet@zeroflux.org>
   4
   5 # NOTE: requires rebuilt with each new gcc version
   6
   7 pkgname=libtool
   8 pkgver=2.4.6+42+gb88cebd5
   9 pkgrel=16
  10 _gccver=11.1.0
  11 pkgdesc='A generic library support script'
  12 arch=(x86_64)
  13 url='https://www.gnu.org/software/libtool'
  14 license=(GPL)
  15 groups=(base-devel)
  16 depends=(sh tar glibc)
  17 makedepends=("gcc>=$_gccver" git help2man)
  18 checkdepends=(gcc-fortran)
  19 provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
  20 conflicts=(libltdl libtool-multilib)
  21 replaces=(libltdl libtool-multilib)
  22 _commit=b88cebd510add4420dd8f5367e3cc6e6e1f267cd
  23 source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit
  24         git+https://git.savannah.gnu.org/git/gnulib.git
  25         gnulib-bootstrap::git+https://github.com/gnulib-modules/bootstrap.git
  26         no_hostname.patch)
  27 sha256sums=('SKIP'
  28             'SKIP'
  29             'SKIP'
  30             '693aabb24a6e7ce21fe0b5d14394e19edcb8476663b5afa4463f9fa0df24d946')
  31
  32 pkgver() {
  33   cd libtool
  34   git describe --tags | sed 's/-/+/g;s/^v//'
  35 }
  36
  37 prepare() {
  38   cd libtool
  39
  40   patch -Np1 -i ${srcdir}/no_hostname.patch
  41
  42   git submodule init
  43   git config --local submodule.gnulib.url "$srcdir/gnulib"
  44   git config --local submodule.gl-mod/bootstrap.url "$srcdir/gnulib-bootstrap"
  45   git submodule update
  46
  47   ./bootstrap
  48 }
  49
  50 build() {
  51   cd libtool
  52   ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
  53   make
  54 }
  55
  56 check() {
  57   cd libtool
  58   make check gl_public_submodule_commit=
  59 }
  60
  61 package() {
  62   cd libtool
  63   make DESTDIR="$pkgdir" install
  64 }