libusb/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   4
   5 pkgname=libusb
   6 pkgver=1.0.24
   7 pkgrel=2
   8 pkgdesc="Library that provides generic access to USB devices"
   9 arch=('x86_64')
  10 url="https://libusb.info/"
  11 license=('LGPL2.1')
  12 depends=('glibc')
  13 makedepends=('systemd')
  14 provides=('libusb-1.0.so')
  15 source=("https://github.com/${pkgname}/${pkgname}/releases/download/v$pkgver/${pkgname}-$pkgver.tar.bz2"
  16         "${pkgname}-1.0.24-descriptor_parsing.patch"
  17 )
  18 sha512sums=('5aea36a530aaa15c6dd656d0ed3ce204522c9946d8d39ffbb290dab4a98cda388a2598da4995123d1032324056090bd429e702459626d3e8d7daeebc4e7ff3dc'
  19             '588624bdcce2ff3ef98ab28b98b00eb48f16ef9e94033f29aaf8c6d6cb3e56d1299ea59f63b0d7a485955fa85182db0db5c043ceca24345c41f40311483606e2')
  20 b2sums=('f6188b5af1225cf8b6d1486b6efcf48e837ee4f2e3592adab3ae6aae0a74a67aa54f40f0dd547f951a194d40954f2ee33acf741d2eee0b8449ce64f2edcf1018'
  21         '65efafcaa87cc75000adb0f6fae6c5fc33d72727bacde327bae5e5e68162783c8203f92ecd3de2f7e8a9869f587ea76a0b1a054369a15cd9b3cec8f7fc44036f')
  22
  23 prepare() {
  24   cd "$pkgname-$pkgver"
  25   patch -Np1 -i ../"${pkgname}-1.0.24-descriptor_parsing.patch"
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd "$pkgname-$pkgver"
  31   ./configure --prefix=/usr
  32   make
  33 }
  34
  35 check() {
  36   cd "$pkgname-$pkgver"
  37   make -k check
  38 }
  39
  40 package () {
  41   depends+=('libudev.so')
  42   cd "$pkgname-$pkgver"
  43   make DESTDIR="$pkgdir" install
  44   install -vDm 644 {AUTHORS,ChangeLog,README} \
  45     -t "${pkgdir}/usr/share/doc/${pkgname}/"
  46 }