pyqt5/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4 # Contributor: Yichao Yu <yyc1992@gmail.com>
   5 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   6 # Contributor: riai <riai@bigfoot.com> Ben <ben@benmazer.net>
   7
   8 pkgbase=pyqt5
   9 pkgname=('python-pyqt5')
  10 pkgdesc="A set of Python bindings for the Qt5 toolkit"
  11 pkgver=5.15.6
  12 pkgrel=4
  13 arch=('x86_64')
  14 url="https://riverbankcomputing.com/software/pyqt/intro"
  15 license=('GPL')
  16 groups=(pyqt5)
  17 depends=('python-pyqt5-sip' 'qt5-base')
  18 optdepends=('python-opengl: enable OpenGL 3D graphics in PyQt applications'
  19             'python-dbus: for python-dbus mainloop support'
  20             'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
  21             'qt5-tools: QtHelp, QtDesigner'
  22             'qt5-svg: QtSvg'
  23             'qt5-webkit: QtWebKit, QtWebKitWidgets'
  24             'qt5-xmlpatterns: QtXmlPatterns'
  25             'qt5-declarative: QtQml, qmlplugin'
  26             'qt5-serialport: QtSerialPort'
  27             'qt5-websockets: QtWebSockets'
  28             'qt5-connectivity: QtNfc, QtBluetooth'
  29             'qt5-x11extras: QtX11Extras'
  30             'qt5-remoteobjects: QtRemoteObjects'
  31             'qt5-speech: QtTextToSpeech'
  32             'qt5-quick3d: QtQuick3D')
  33 provides=(qt5-python-bindings)
  34 makedepends=('sip' 'pyqt-builder' 'python-opengl' 'python-dbus'
  35              'qt5-connectivity' 'qt5-multimedia' 'qt5-tools' 'qt5-serialport' 'qt5-speech' 'qt5-svg'
  36              'qt5-webkit' 'qt5-websockets' 'qt5-x11extras' 'qt5-xmlpatterns' 'qt5-remoteobjects' 'qt5-quick3d')
  37 conflicts=('pyqt5-common')
  38 source=("https://pypi.python.org/packages/source/P/PyQt5/PyQt5-$pkgver.tar.gz"
  39          restore-sip4-support.patch)
  40 sha256sums=('80343bcab95ffba619f2ed2467fd828ffeb0a251ad7225be5fc06dcc333af452'
  41             'c8881a8dc666e509773f93330615d310f9f040c2167dc9e98843741691395f72')
  42
  43 prepare() {
  44   patch -d PyQt5-$pkgver -p1 < restore-sip4-support.patch # https://www.riverbankcomputing.com/pipermail/pyqt/2021-November/044346.html
  45 }
  46
  47 build() {
  48   cd PyQt5-$pkgver
  49   sip-build \
  50     --confirm-license \
  51     --no-make \
  52     --api-dir /usr/share/qt/qsci/api/python
  53   cd build
  54   make
  55 }
  56
  57 package_python-pyqt5(){
  58   cd PyQt5-$pkgver/build
  59   make INSTALL_ROOT="$pkgdir" install -j1
  60
  61   # Remove unused py2 version of uic modules:
  62   rm -r "$pkgdir"/usr/lib/python*/site-packages/PyQt5/uic/port_v2
  63
  64   # compile Python bytecode
  65   python -m compileall -d / "$pkgdir"/usr/lib
  66   python -O -m compileall -d / "$pkgdir"/usr/lib
  67 }