sysprof/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Geoffroy Carrier <geoffroy.carrier@aur.archlinux.org>
   4 # Contributor: Eric Belanger <belanger@astro.umontreal.ca>
   5 # Contributor: aeolist <aeolist@hotmail.com>
   6 # Contributor: Gabriel Rauter <rauter.gabriel@gmail.com>
   7
   8 pkgname=sysprof
   9 pkgver=3.42.1
  10 pkgrel=1
  11 pkgdesc="Kernel based performance profiler"
  12 url="https://wiki.gnome.org/Apps/Sysprof"
  13 license=(GPL)
  14 arch=(x86_64)
  15 depends=(gtk3 polkit libdazzle)
  16 makedepends=(yelp-tools git meson)
  17 groups=(gnome-extra)
  18 _commit=2903f08d02c86e520b07c0df5dcafc18bb8ef059  # tags/3.42.1^0
  19 source=("git+https://gitlab.gnome.org/GNOME/sysprof.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 _gccver=11
  23 makedepends+=("gcc>=$_gccver" "gcc<$((_gccver + 1))")
  24 conflicts+=("gcc<$_gccver" "gcc>=$((_gccver + 1))")
  25
  26 pkgver() {
  27   cd $pkgname
  28   git describe --tags | sed 's/^sysprof-//;s/-/+/g'
  29 }
  30
  31 prepare() {
  32   cd $pkgname
  33 }
  34
  35 build() {
  36   # Ensure static library is non-LTO compatible
  37   CFLAGS+=" -ffat-lto-objects"
  38
  39   arch-meson $pkgname build
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   meson test -C build --print-errorlogs
  45 }
  46
  47 package() {
  48   meson install -C build --destdir "$pkgdir"
  49 }