tracker3-miners/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=tracker3-miners
   4 pkgver=3.2.1
   5 pkgrel=2
   6 pkgdesc="Collection of data extractors for Tracker/Nepomuk"
   7 url="https://wiki.gnome.org/Projects/Tracker"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(tracker3 gst-plugins-base-libs exempi libexif libcue libgrss libgsf
  11          libgxps libiptcdata libosinfo poppler-glib totem-plparser giflib
  12          libgexiv2 gupnp-dlna upower libseccomp libnm)
  13 makedepends=(git meson vala asciidoc)
  14 checkdepends=(python-gobject python-tappy gst-plugins-good gst-plugins-base
  15               gst-libav)
  16 groups=(gnome)
  17 _commit=1e1a9e701faae73148fc05613b7e237715ad0cc9  # tags/3.2.1^0
  18 source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd tracker-miners
  23   git describe --tags | sed 's/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd tracker-miners
  28 }
  29
  30 build() {
  31   arch-meson tracker-miners build -D tests_tap_protocol=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
  37   dbus-run-session meson test -C build --print-errorlogs -t 3 || :
  38 }
  39
  40 package() {
  41   depends+=(libtracker-sparql-3.0.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44 }