xawtv/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
   3 # Contributor: Jason Chu <jason@archlinux.org>
   4
   5 pkgname=xawtv
   6 pkgver=3.107
   7 pkgrel=1
   8 pkgdesc="A simple Xaw-based TV program which uses the bttv driver or video4linux"
   9 arch=('x86_64')
  10 url="https://git.linuxtv.org/xawtv3.git"
  11 license=('GPL')
  12 depends=('aalib' 'v4l-utils' 'libxv' 'libxrandr' 'libgl' 'libdv' 'zvbi' 'libxinerama' 'lirc' 'libxft' 'libxaw' 'xorg-fonts-misc' 'libxxf86vm')
  13 makedepends=('mesa' 'git' 'xorgproto')
  14 _commit=8e3feea862db68d3ca0886f46cd99fab45d2db7c
  15 source=("git+https://git.linuxtv.org/cgit.cgi/xawtv3.git#commit=$_commit")
  16 md5sums=('SKIP')
  17
  18 pkgver() {
  19   cd xawtv3
  20   git describe --tags | sed 's/^xawtv-//;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd xawtv3
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28 build() {
  29   cd "${srcdir}/xawtv3"
  30   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  31   ./configure --prefix=/usr --disable-motif --disable-quicktime
  32   make
  33 }
  34
  35 package() {
  36   cd "${srcdir}/xawtv3"
  37   make DESTDIR="${pkgdir}" install
  38 }