egl-wayland/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=egl-wayland
   4 pkgver=1.1.11
   5 pkgrel=2
   6 epoch=2
   7 pkgdesc="EGLStream-based Wayland external platform"
   8 url="https://github.com/NVIDIA/egl-wayland"
   9 arch=(x86_64)
  10 license=(MIT)
  11 depends=(wayland eglexternalplatform)
  12 makedepends=(meson git wayland-protocols 'libglvnd>=1.3.4')
  13 provides=(libnvidia-egl-wayland.so)
  14 options=(debug)
  15 _commit=1bac4260aa89c4938246798f3a141500ed9daa10  # tags/1.1.11
  16 source=("git+$url#commit=$_commit"
  17         10_nvidia_wayland.json)
  18 sha256sums=('SKIP'
  19             '5cccf1905a266e8e34d5ad4aad4be85390e60b1a0850a29dd9d64adc641de412')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28 }
  29
  30 build() {
  31   arch-meson $pkgname build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41   install -Dt "$pkgdir/usr/share/egl/egl_external_platform.d" -m644 10_nvidia_wayland.json
  42   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
  43 }
  44
  45 # vim:set sw=2 sts=-1 et: